class – SAP EWM Help

What is an Interface in SAP ABAP?

DPM125 — Sun, 03 Aug 2025 06:42:49 +0000

An interface in ABAP defines a contract that any implementing class must follow. It contains only declarations of:

Methods (without implementation)
Constants
Types
Attributes

Interfaces do not contain implementation. Any class that implements an interface must provide the logic for all its methods.

Feature	Description
No implementation	Only method signatures are defined.
Multiple interfaces	A class can implement more than one interface.
Full implementation required	All interface methods must be implemented in the class.
Promotes loose coupling	Ideal for modular, testable, flexible code.

Code:

REPORT zrep_lclclass.

INTERFACE if_animal.
  METHODS:
    speak,
    move.
ENDINTERFACE.

" Class that implements the interface
CLASS lcl_dog DEFINITION.
  PUBLIC SECTION.
    INTERFACES: if_animal.
ENDCLASS.

CLASS lcl_dog IMPLEMENTATION.
  METHOD if_animal~speak.
    WRITE: 'Woof!'.
  ENDMETHOD.

  METHOD if_animal~move.
    WRITE: 'Dog is running'.
  ENDMETHOD.
ENDCLASS.

START-OF-SELECTION.
  DATA(lo_dog) = NEW lcl_dog( ).
  lo_dog->if_animal~speak( ).
  lo_dog->if_animal~move( ).

Output:

What is an Abstract Class in SAP ABAP?

DPM125 — Sun, 03 Aug 2025 06:37:17 +0000

An abstract class is a class that cannot be instantiated directly. It serves as a blueprint for other classes. Abstract classes typically include:

Abstract methods, which are declared but not implemented.
Concrete methods, which can be implemented and inherited.

Feature	Description
Not instantiable	Cannot use `CREATE OBJECT` on abstract classes.
Used for inheritance	Serve as base classes for child classes.
Can contain abstract methods	These must be implemented in subclasses.
Can contain concrete methods	These can be used directly by child classes.

REPORT zrep_lclclass.

CLASS lcl_animal DEFINITION ABSTRACT.
  PUBLIC SECTION.
    METHODS:
      speak ABSTRACT,
      move.         " This can be implemented if needed
ENDCLASS.

CLASS lcl_animal IMPLEMENTATION.
  METHOD move.
    WRITE: 'Animal is moving'.
  ENDMETHOD.
ENDCLASS.

" Concrete subclass
CLASS lcl_dog DEFINITION INHERITING FROM lcl_animal.
  PUBLIC SECTION.
    METHODS:
      speak REDEFINITION.
ENDCLASS.

CLASS lcl_dog IMPLEMENTATION.
  METHOD speak.
    WRITE: 'Woof!'.
  ENDMETHOD.
ENDCLASS.

START-OF-SELECTION.
  " Parent Class
  DATA(lo_animal) = NEW lcl_animal( ).
  lo_animal->speak( ).
  WRITE: 'Animal can speak'.
  SKIP.
  " child class
  DATA(lo_dog) = NEW lcl_dog( ).
  lo_dog->speak( ).
  lo_dog->move( ).

Output:
Check the Program ( CTRL + F2 ).

if not initated the Parent class then the output will be.

Output:

Constructor in ABAP

DPM125 — Thu, 31 Jul 2025 20:15:51 +0000

A constructor is a special method automatically called when an object is created using CREATE OBJECT or NEW.

Types of Constructors in ABAP

Type	Method Name	Called On	Purpose
Instance Constructor	`CONSTRUCTOR`	When an object is created (`NEW` or `CREATE OBJECT`)	To initialize instance-specific data
Class Constructor	`CLASS_CONSTRUCTOR`	When the class is first used	To initialize class-level (static) data

REPORT zrep_lclclass.

CLASS zcl_demo DEFINITION.
  PUBLIC SECTION.
    METHODS: constructor,               " Instance constructor
             display_instance_value.

    CLASS-METHODS: class_constructor,  " Class constructor
                   display_class_value.

  PRIVATE SECTION.
    DATA: lv_instance_val TYPE string.
    CLASS-DATA: gv_class_val TYPE string.
ENDCLASS.

CLASS zcl_demo IMPLEMENTATION.

  " Instance Constructor
  METHOD constructor.
    lv_instance_val = 'Initialized in CONSTRUCTOR'.
    WRITE: / '>> Instance CONSTRUCTOR called'.
  ENDMETHOD.

  " Class Constructor
  METHOD class_constructor.
    gv_class_val = 'Initialized in CLASS_CONSTRUCTOR'.
    WRITE: / '>> CLASS_CONSTRUCTOR called (only once)'.
  ENDMETHOD.

  METHOD display_instance_value.
    WRITE: / 'Instance value:', lv_instance_val.
  ENDMETHOD.

  METHOD display_class_value.
    WRITE: / 'Class value:', gv_class_val.
  ENDMETHOD.

ENDCLASS.

START-OF-SELECTION.

* Access class method (triggers class constructor first time)
  zcl_demo=>display_class_value( ).

  SKIP.

* Create object (triggers instance constructor)
  DATA(lo_obj1) = NEW zcl_demo( ).
  lo_obj1->display_instance_value( ).

  SKIP.

* Create another object (instance constructor runs again, but not class constructor)
  DATA(lo_obj2) = NEW zcl_demo( ).
  lo_obj2->display_instance_value( ).

  SKIP.

* Access class method again (class constructor NOT triggered again)
  zcl_demo=>display_class_value( ).

Output:

What is Singleton Class ? how to use Singleton class in SAP ABAP ?

DPM125 — Thu, 31 Jul 2025 19:28:18 +0000

A Singleton class is a design pattern that restricts the instantiation of a class to one single object throughout the lifecycle of a program. This is useful when exactly one object is needed to coordinate actions across the system — such as logging, configuration management, or connection handling.

Key Characteristics of Singleton Pattern:

Only one instance of the class exists.
The class controls its own instantiation.
A global access point is provided to access.

*&---------------------------------------------------------------------*
*& Report  ZREP_LCLCLASS
*&
*&---------------------------------------------------------------------*
*&
*&
*&---------------------------------------------------------------------*

REPORT zrep_lclclass.

CLASS lcl_class_singleton DEFINITION CREATE PRIVATE.
  PUBLIC SECTION.
  " to check the instance is created or not.
    CLASS-METHODS: m_factory RETURNING VALUE(r_instance) TYPE REF TO lcl_class_singleton.
  " getter and setter methods
    METHODS : get_attribute RETURNING VALUE(r_attribute) TYPE i,
              set_attribute IMPORTING m_attribute TYPE i.

  PRIVATE SECTION.
*    CLASS-DATA: obj_instance TYPE REF TO lcl_class_singleton.
    DATA gv_attribute TYPE i.
ENDCLASS.

class lcl_class_singleton IMPLEMENTATION.
    method m_factory.
        if r_instance is not BOUND.
            r_instance = new lcl_class_singleton( ).
        endif.
   ENDMETHOD.

   method get_attribute.
       r_Attribute = gv_Attribute.
   ENDMETHOD.

   method set_attribute.
     gv_Attribute =  m_attribute.
   ENDMETHOD.
 ENDCLASS.

 START-OF-SELECTION.
 " create an instance of class
   data(lo_obj) =  lcl_class_singleton=>m_factory( ).
 " set the value for the attribute.
   lo_obj->set_attribute( 10 ).

   " try to create another instace of the class.
    data(lo_obj2) = lcl_class_singleton=>m_factory( ).
   " check the attribute of the new instance
   " it should be same as go_obj as it contains a static attribute
   " get the data and print it.
   write: 'First object attribute value ', lo_obj->get_attribute( ).
   write :/ 'Second object attribute value ', lo_obj2->get_attribute( ).

Output:

What is the difference between static and instance Members in SAP OOABAP ?

DPM125 — Wed, 30 Jul 2025 17:30:46 +0000

Instance Members (Methods & Data)

Belong to individual objects (instances).
Created using DATA and METHODS.
Each object has its own copy of the data.
Accessed using the object reference: lo_obj->method_name.
Useful when each object should maintain its own state.
Destroyed when the object goes out of scope.

Static Members (Methods & Data)

Belong to the class itself, not any particular object.
Created using CLASS-DATA and CLASS-METHODS.
Only one copy exists for the entire class.
Accessed using the class name: zcl_class_name=>method_name.
Useful for shared data, like counters, configuration, or logging.
Exist as long as the class is loaded in memory.

*&---------------------------------------------------------------------*
*& Report  ZREP_LCLCLASS
*&
*&---------------------------------------------------------------------*
*&
*&
*&---------------------------------------------------------------------*

REPORT zrep_lclclass.

CLASS zcl_static_instance_demo DEFINITION.
  PUBLIC SECTION.
    " Instance attribute and method
    DATA: gv_instance_value TYPE i.
    METHODS: increase_instance_value.

    " Static attribute and method
    CLASS-DATA: gv_static_value TYPE i.
    CLASS-METHODS: increase_static_value.
ENDCLASS.

CLASS zcl_static_instance_demo IMPLEMENTATION.

  METHOD increase_instance_value.
    gv_instance_value = gv_instance_value + 1.
    WRITE: / 'Instance Value:', gv_instance_value.
  ENDMETHOD.

  METHOD increase_static_value.
    gv_static_value = gv_static_value + 1.
    WRITE: / 'Static Value:', gv_static_value.
  ENDMETHOD.

ENDCLASS.

START-OF-SELECTION.

  WRITE: / '--- Static Method Calls (No object needed) ---'.
  zcl_static_instance_demo=>increase_static_value( ). " 1
  zcl_static_instance_demo=>increase_static_value( ). " 2

  SKIP.

  WRITE: / '--- Instance Method Calls (Using object) ---'.
  DATA(lo_obj1) = NEW zcl_static_instance_demo( ).
  lo_obj1->increase_instance_value( ). " 1
  lo_obj1->increase_instance_value( ). " 2

  SKIP.

  WRITE: / '--- Another Object with Separate Instance ---'.
  DATA(lo_obj2) = NEW zcl_static_instance_demo( ).
  lo_obj2->increase_instance_value( ). " 1 (separate from lo_obj1)

  SKIP.

  WRITE: / '--- Static Again (Still shared) ---'.
  zcl_static_instance_demo=>increase_static_value( ). " 3

Output :

Use of Me Keyword in SAP ABAP

DPM125 — Tue, 29 Jul 2025 19:32:30 +0000

When we create a variable in the public section of a class, we can use it within the methods of that class. Let’s say we assign it an initial value. Later, if we create another variable with the same name inside a method and assign it a new value, this new (local) value will be used within that method.

To access the original value from the class, we need to use the ME operator.

Example:

We first create a public variable v_txt with an initial value ‘Class Variable’. Then, inside a method, we declare another variable (local to the method) with the same name v_txt, but assign it a different value: ‘Method Variable’.

If we use v_txt directly in the method, it will reference the local variable, and we will get ‘Method Variable’.

If we use me->v_txt, we explicitly refer to the class attribute, and we get ‘Class Variable’.

Similarly, private and protected methods cannot be accessed directly from outside the class. However, we can call them from within another public method using the ME operator.

*&---------------------------------------------------------------------*
*& Report  ZREP_LCLCLASS
*&
*&---------------------------------------------------------------------*
*&
*&
*&---------------------------------------------------------------------*

REPORT zrep_lclclass.

" local class definition.
CLASS lcl_operator  DEFINITION.

  PUBLIC SECTION.

    DATA : v_txt TYPE string VALUE 'Class Variable'.
    METHODS: m_operator.
    
  PROTECTED SECTION.
    METHODS: m_protectedmethod.
    
  PRIVATE SECTION.
    METHODS: m_privatemethod.
ENDCLASS.

" local class implementation
CLASS lcl_operator IMPLEMENTATION.
  METHOD m_protectedmethod.
    WRITE :/ 'Hi from protected method'.
  ENDMETHOD.
  METHOD m_privatemethod.
    WRITE :/ 'Hi from private method'.
  ENDMETHOD.
  METHOD m_operator.
    DATA v_txt TYPE string VALUE 'Method Variable'.

    WRITE: / v_txt,
           / me->v_txt.
    me->m_protectedmethod( ). " protected method
    me->m_privatemethod( ). " private method
  ENDMETHOD.
ENDCLASS.


START-OF-SELECTION.

  " object for class.
  DATA(lo_class) = NEW lcl_operator( ).
  lo_class->m_operator( ).

OUTPUT :